Analytical solution to Eq. (102)

DR Ladiges & JE Sader
"A variational method enabling simplified solutions to the linearized Boltzmann equation for oscillatory gas flows"
Physical Review Fluids (2018)

This notebook derives the analytical solution to Eq. (102) where (Subscript[(OverTilde[u]), gf,x])=0. Results for bulk velocity and shear stress are shown in the ‘Bulk flow results’ cell.

N = 2 matrix

The matrix representing the system of equations derived using the variational method.

matrixN2={{(Sqrt[π]) (1-2 I θ),I θ(-4+π) +3-π,-(Sqrt[π]),1},{-(-2+π) (1-2 I θ),((-2+π)/( (Sqrt[π]) )),-2+π,((2-π)/( (Sqrt[π]) ))},{(Sqrt[π]),1,-(Sqrt[π]) (1-2 I θ),I θ(-4+π)+3-π},{-2+π,((-2+π)/((Sqrt[π]) )),-(-2+π) (1-2 I θ),((2-π)/( (Sqrt[π]) ))}};
{eVal,eVec}=Eigensystem[matrixN2];

Solution

Solution given as a sum of exponentials. Two constants are determined by requiring a finite solution, the other two are evaluated using the boundary conditions.

solutionMatrix=Table[Sum[c[ii]eVec[[ii,jj]]Exp[eVal[[ii]](y/((-4+π) θ))],{ii,1,4}],{jj,1,4}]/.c[1]->0/.c[3]->0;
(* Constants c[1] and c[3] are set to zero to remove terms increasing as y->∞ *)

solutionTop=solutionMatrix/.y->Y;
solutionBottom=solutionMatrix/.y->0;

applyBCs={solutionBottom[[1]]==2,solutionBottom[[2]]==0,solutionTop[[3]]==0,solutionTop[[4]]==0}/.(E^(_))-> 0;
(* The replacment /.(E^(_))-> 0 removes terms which vanish as Y -> ∞ *)

solveBCs=Solve[applyBCs,{c[2],c[4]}];

solutionMatrixWithBCs=solutionMatrix/.solveBCs;

Bulk flow results

Equations (53) and (63) applied to obtain bulk velocity and shear stress.

basis = {cx, cx cy};

uTop=Integrate[cx basis (1/(π^(3/2))) Exp[-((cx^2)+(cy^2)+(cz^2))],{cy,-∞,0},{cz,-∞,∞},{cx,-∞,∞}];
uBottom=Integrate[cx basis (1/(π^(3/2))) Exp[-((cx^2)+(cy^2)+(cz^2))],{cy,0,∞},{cz,-∞,∞},{cx,-∞,∞}];

τTop=Integrate[cx cy basis (1/(π^(3/2))) Exp[-((cx^2)+(cy^2)+(cz^2))],{cy,-∞,0},{cz,-∞,∞},{cx,-∞,∞}];
τBottom=Integrate[cx cy basis (1/(π^(3/2))) Exp[-((cx^2)+(cy^2)+(cz^2))],{cy,0,∞},{cz,-∞,∞},{cx,-∞,∞}];

Bulk velocity field

u[y_,θ_]=solutionMatrixWithBCs[[1,1;;2]].uBottom+solutionMatrixWithBCs[[1,3;;4]].uTop;

Shear stress field

τ[y_,θ_]=solutionMatrixWithBCs[[1,1;;2]].τBottom+solutionMatrixWithBCs[[1,3;;4]].τTop;